IRA Planner

Richard and Betty Givan
Richmond, KY

You've seen the bank ads: "Retire a Millionaire." Type in this short program (it will run on Atari, Radio Shack Color Computer, PET/CBM, VIC, and Apple) and see for yourself how IRA accounts compute. The program uses very little memory. The "^" symbol means "to the power of."

Most get-rich schemes of the past have proven to be of questionable legality and dubious worth. The latest promotion, however, is endorsed by the US Government and seems foolproof. This device is the Individual Retirement Account (IRA), expanded in 1982 to allow up to a $2000 ($2250 in a joint plan with a nonworking spouse) yearly deposit to be put into a private retirement account.

This amount is deductible from the person's gross income during the year deposited, decreasing the income tax accordingly. The retirement fund is then free to grow at the prevailing competitive interest rate – compounded daily and tax free – until it is withdrawn during retirement. Although taxes are then due, presumably the taxpayer will be in a lower tax bracket and so pay a lesser tax.

The Relationship Between Inflation And Interest

The allure of the plan is in the rapid growth of the principal through compound interest at the currently high rates. Hence the ads in which banks all but guarantee that you can be a millionaire upon retirement via a $2000 yearly deposit for 35 years at a 12% return. Actually, your account would be worth an astounding $1,161,059. Such a modest sacrifice in order to retire a millionaire!

As with all get-rich plans, however, there is a catch – not a legal or even an ethical one, but a matter of economics. The IRA promotion campaigns conveniently overlook the devastating effects of inflation on your million. At the same time that compound interest is building your fortune, inflation is eroding it. Historically, the interest rate is fairly well dictated by the rate of inflation. Although temporary imbalances occur, economists generally agree that, in the long run, the interest rate will seek out a level approximately three to four percent higher than the inflation rate.

Assuming that the prevailing inflation rate (say nine percent) holds steady, your retirement fortune of $ 1,161,059 from the above example will really be worth only $56,875 in the purchasing power of 1982 dollars. You may have a carload of dollars in the year 2017, but the Cadillac you buy to haul it home would cost $306,000 and the gasoline to power it would be $25 a gallon!

This is not to say that an IRA is a bad way to save. It does offer immediate tax relief, and that in itself might provide you with the incentive to put aside some funds for your golden years. But it would be well to put the numbers in perspective when planning for your future.

The program asks you several questions: the amount of money you wish to set aside each year; the tax bracket you are currently in (which can be found by reference to the IRS booklet accompanying your tax forms, but is not really essential to the rest of the program); your age when you begin and end the plan; and the average interest and inflation rates you expect to experience (here's where a crystal ball program would be nice).

The program then displays the tax savings you would receive the first year in the plan. (Income and tax rate would probably fluctuate too much to benefit from attempting to compute these over the life of your IRA.) The sum of your deposits is displayed, followed by the principal of the account increased by accumulated interest. Then the real spending power of your final nest egg is shown by reducing the principal to reflect the inflation rate. You can see its worth in terms of the 1982 dollar. Bear in mind that this money is taxable when withdrawn, also. You can then easily experiment with different interest and inflation rates at this point without having to answer the other questions again.

One note: the two questions about inflation and interest ask for the figures expressed as decimals. In other words, if you want to answer 12% inflation, you should type .12 and 6% interest would be entered as .06.

10 REM IRA PLANNER
30 DIM A$(1) : REM THIS LINE ONLY NECESSARY ~ FOR ATARI
40 PRINT "AT WHAT AGE DO YOU PLAN"
50 PRINT "TO OPEN AN IRA ACCOUNT" ; : INPUT A
60 PRINT : PRINT "AT WHAT AGE DO YOU PLAN TO ~ RETIRE" ; : INPUT A1
70 Y = A1 - A
80 PRINT : PRINT "HOW MUCH DO YOU PLAN TO"
90 PRINT "DEPOSIT PER YEAR" ; : INPUT D : C = D
100 PRINT : PRINT "WHAT IS YOUR TAX BRACKET?"
110 PRINT "(ENTER PERCENTAGE EXPRESSED" : PRINT "AS A DECIMAL)" : INPUT P
120 PRINT : PRINT "WHAT IS THE AVERAGE INTEREST RATE YOU
130 PRINT "EXPECT FOR THE ACCOUNT OVER THE
140 PRINT "YEARS IT EXISTS? (ENTER PERCENTAGE
150 PRINT "EXPRESSED AS A DECIMAL)" : INPUT R
160 PRINT : PRINT "WHAT IS THE AVERAGE INFLATION RATE"
170 PRINT "YOU EXPECT DURING THE YEARS"
180 PRINT "BETWEEN OPENING THE ACCOUNT AND
190 PRINT "RETIREMENT? (ENTER PERCENTAGE
195 PRINT "EXPRESSED AS A DECIMAL)" : INPUT I
200 S = D*P
210 PRINT : PRINT "YOU WILL SAVE $" ; INT(S); " ON TAXES THIS YEAR."
220 T = D*Y
230 PRINT : PRINT "THE TOTAL AMOUNT DEPOSITED ~ INTO YOUR
240 PRINT "IRA ACCOUNT OVER THE "; Y ;" YEARS ~ IS" : PRINT "$"; INT(T); "."
250 FOR J = 1 TO Y
260 X = D* (1 + R/365)^365
270 D = X + C
280 NEXT J
290 PRINT : PRINT "WHEN YOU RETIRE, THE AMOUNT IN YOUR"
300 PRINT "ACCOUNT WILL BE $" ; INT(X); "."
310 Z = (1 + I)^Y
320 W = X/Z
330 PRINT : PRINT " ... WHICH IS WORTH $" ; INT(W) ;" IN 1982"
340 PRINT "DOLLARS."
350 PRINT : PRINT "WOULD YOU LIKE TO TRY THIS ~ AGAIN WITH
360 PRINT "DIFFERENT INTEREST AND INFLATION ~ RATES"
370 PRINT "(Y OR N)" ; : INPUT A$
380 IF A$ = "N" THEN END
390 D = C : GOTO 120